Hi Kenneth,

I've removed your email address. Also, you make some pretty good points. Here are my responses and some sample code:

a) Definitely. I have toyed with some ideas of how to remove the chr(0) padding that comes back from a decrypted string. Since these are block ciphers, the return is padded. One way to do this would be to add a byte to the encrypted text that would tell the decryption algorithm how many bytes are padded, then it could remove them before returning. For now, you are using the correct way to remove them, though concatenating a chr(0) flag when it is encrypted would also be a good idea (see my code below)

b)Encrypt is only a reserved word because there is a little known SET statement... SET ENCRYPTION ON/OFF - this has no effect on the VFP environment however. Perhaps the MS Fox Team was thinking about giving us native encryption at one time? There are no compatibility errors with using Encrypt, even though it is tagged as a keyword.

c)The API exception is caused because the encryption string you are sending into the decrypt function is invalid. Below is some working example code for you to try. I've commented to code so you can see what I am doing. Even with the additional machinations, I think you will find that the code is extremely fast when used with a much larger data set.

*!* Example of use
#DEFINE PRIVATEKEY "ISTOTALSECRETKEY"
CREATE CURSOR crsPeople (firstname c(25))
INSERT INTO crsPeople (firstname) VALUES ("Craig")
INSERT INTO crsPeople (firstname) VALUES ("Kenneth")
INSERT INTO crsPeople (firstname) VALUES ("Sue")
INSERT INTO crsPeople (firstname) VALUES ("Claire")
INSERT INTO crsPeople (firstname) VALUES ("Bill")

SET LIBRARY TO LOCFILE("vfpencryption.fll")
*!* For encryption we don't want the field padding to be included
*!* We also set a flag that shows where the encryption ends by using Chr(0)
replace ALL firstname WITH Encrypt(ALLTRIM(firstname), PRIVATEKEY, 8, 0) + CHR(0) IN "crsPeople"
BROWSE && All field values are encrypted
*!* For decryption we want to check for the flag chr(0) and grab everything before it using Left() and RAT()
*!* Then we want to strip any Chr(0) padding from the decrypted block
replace ALL firstname WITH CHRTRAN(Decrypt(LEFT(firstname, RAT(CHR(0), firstname) - 1), PRIVATEKEY, 8, 0), CHR(0), "") IN "crsPeople" && key is 16 bytes
BROWSE && All field values are decrypted

The problem with encrypting all the spaces or even encrypting the contents of a field that is filled in completely is that the original space is not large enough to handle the encrypted text. Case in point... let's say you have a 25 character field as I've shown above. Using TEA for instance the ciphertext for that 25 character field will be 32 characters long. This is because in block ciphers it deals with blocks of data, unlike a stream cipher. So, when you go to replace the field with the 32 bytes of ciphertext, it will be truncated at 25 bytes and result in the decrypt routine throwing an error. There's no easy answer to this, I'm afraid. I could pad the encrypted string with the total length of padding, and then truncate that during decryption, but then it would be difficult for a developer to tell how long they must make the field to accomodate it. Maybe a bigger problem than what we have now?

In the following example, I've modified the code I posted above that should clearly show that it is the size of the fields (and subsequent padding done by a block cipher) that is causing the problem. Try this:

*!* Example of use
#DEFINE PRIVATEKEY "ISTOTALSECRETKEY"
CREATE CURSOR crsPeople (firstname c(32)) && note I have changed fieldsize from 25 to 32 (any multiple of 8 will work for TEA: 16, 24, 40, 48, etc.)
INSERT INTO crsPeople (firstname) VALUES ("Craig")
INSERT INTO crsPeople (firstname) VALUES (" ")
INSERT INTO crsPeople (firstname) VALUES ("Kenneth")
INSERT INTO crsPeople (firstname) VALUES (" ")
INSERT INTO crsPeople (firstname) VALUES ("Sue")
INSERT INTO crsPeople (firstname) VALUES (" ")
INSERT INTO crsPeople (firstname) VALUES ("Claire")
INSERT INTO crsPeople (firstname) VALUES (" ")
INSERT INTO crsPeople (firstname) VALUES ("Bill")

SET LIBRARY TO LOCFILE("vfpencryption.fll")
replace ALL firstname WITH Encrypt(firstname, PRIVATEKEY, 8, 0) IN "crsPeople"
BROWSE && All field values are encrypted
replace ALL firstname WITH Decrypt(firstname, PRIVATEKEY, 8, 0) IN "crsPeople" && key is 16 bytes
BROWSE && All field values are decrypted

Hi Kenneth,

I'm working on adding RC4, PIKE, SEAL, and PC1 stream ciphers to the library, however for right now it only provides block ciphers and hash functions. If you can wait until just after I present at Southwest Fox then I think I will be able to get you what you need in this FLL. For a more immediate solution you may want to try using CAPICOM from MS which provides access to RC4.